topic Re: Setting up ARB using ASP Classic in Integration and Testing

Setting up ARB using ASP Classic

dzarro — Mon, 22 Mar 2010 12:27:29 GMT

Does anyone know of any resources to get help setting up ARB using ASP Classic? I keep getting errors regarding the XML submission. The latest error is "Invalid at the top level of the document. Error processing resource..." I am fairly confident that there are not errors in the XML, so there must be something in the submission or the retrieval of the response.

The only sample files provided show the XML, not how to submit it. I need help posting XML. I have coded ASP for years, but have never had to do XML before now.

Thanks for any help.

Re: Setting up ARB using ASP Classic

soundcommerce — Mon, 22 Mar 2010 13:07:29 GMT

Greetings,

Please post a code sample on how you're parsing the xml document.

Thank You!

Re: Setting up ARB using ASP Classic

dzarro — Mon, 22 Mar 2010 13:19:13 GMT

Thank you for looking at this.

This is the XML...

strXml = "<?xml version='1.0' encoding='utf-8'?>"
strXml = strXml & "<ARBCreateSubscriptionRequest xmlns='AnetApi/xml/v1/schema/AnetApiSchema.xsd'>"
strXml = strXml & "<merchantAuthentication>"
strXml = strXml & "<name>ACC Test</name>"
strXml = strXml & "<transactionKey>" & strTransKey & "</transactionKey>"
strXml = strXml & "</merchantAuthentication>"
strXml = strXml & "<refId>" & KID & "</refId>"
strXml = strXml & "<subscription>"
strXml = strXml & "<name>Cockapoo Find Member Subscription</name>"
strXml = strXml & "<paymentSchedule>"
strXml = strXml & "<interval>"
strXml = strXml & "<length>1</length>"
strXml = strXml & "<unit>months</unit>"
strXml = strXml & "</interval>"
strXml = strXml & "<startDate>" & date() & "</startDate>"
strXml = strXml & "<totalOccurrences>12</totalOccurrences>"
'strXml = strXml & " <trialOccurrences>1</trialOccurrences>" & vbcrlf
strXml = strXml & "</paymentSchedule>"
strXml = strXml & "<amount>" & request.Form("amt2") & "</amount>"
'strXml = strXml & " <trialAmount>0.00</trialAmount>" & vbcrlf
strXml = strXml & "<payment>"
strXml = strXml & "<creditCard>"
strXml = strXml & "<cardNumber>" & txtCCNum & "</cardNumber>"
strXml = strXml & "<expirationDate>" & txtCCExp & "</expirationDate>"
strXml = strXml & "</creditCard>"
strXml = strXml & "</payment>"
strXml = strXml & "<billTo>"
strXml = strXml & "<firstName>" & txtBillingFName & "</firstName>"
strXml = strXml & "<lastName>" & txtBillingLName & "</lastName>"
strXml = strXml & "<address>" & txtBillingAddress & "</address>"
strXml = strXml & "<zip>" & txtBillingZip & "</zip>"
strXml = strXml & "</billTo>"
strXml = strXml & "</subscription>"
strXml = strXml & "</ARBCreateSubscriptionRequest>"

---------------------

And this is the code that sends it.....

Set objXMLDOC = Server.CreateObject("Msxml2.ServerXMLHTTP.3.0")
Set objXMLDOM = Server.CreateObject("Msxml2.DomDocument")
Set oNode = Server.CreateObject("Microsoft.XMLDOM")

'SET CALL TIMEOUTS
lResolve = 8 * 1000 'Timeout values are in milli-seconds
lConnect = 8 * 1000
lSend = 10 * 1000
lReceive = 10 * 1000
objXMLDOC.setTimeouts lResolve, lConnect, lSend, lReceive

'MAKE THE CALL
objXMLDOC.open "POST", post_url, False
objXMLDOC.setRequestHeader "Content-Type", "text/xml"
objXMLDOC.send(strXml)
objXMLDOM.async = false
objXMLDOM.LoadXML objXMLDOC.responseText
'set objXMLDOM = objXMLDOC.responseXML

'PROCESS THE CALL
If objXMLDOM.parseError.errorCode <> 0 Then 'parser error found
Response.Write "parser error found"
Else 'no parser error
'BEGIN CHECK FOR ERROR FROM Authorize.net
Set oNode = objXMLDOM.getElementsByTagName("*")
Response.Write "oNode length = " & oNode.length & " "
If (Not oNode Is Nothing) Then
Response.Write oNode.item(0).text & " "
Else
'PROCESS SUCCESSFUL CALL
Set oNode = objXMLDOM.getElementsByTagName("subscriptionId")
If (Not oNode Is Nothing) Then
Response.Write "subscriptionId returned" & " "
else
Response.Write "subscriptionId not returned" & " "
End If

'End If

'CLEAN UP EVERYTHING
Set objXMLDOC = Nothing
Set objXMLDOM = Nothing
Set oNode = Nothing

End If
End If

Re: Setting up ARB using ASP Classic

soundcommerce — Mon, 22 Mar 2010 18:52:58 GMT

Greetings,

Please try processing the root node first. Seems like the DOM Parser can't find the subscriptionId element without processing the root element first.

ARBCreateSubscriptionResponse <-- Root Element

Re: Setting up ARB using ASP Classic

dzarro — Tue, 23 Mar 2010 01:44:30 GMT

It turns out that I had three problems. The authorization name was not correct. The date format was not correct. And I was not properly parsing the return XML. I ended up hiring one of the certified developers to help me troubleshoot the problem. He was willing to fix it for a reasonable price. It wasn't very "broken" so it did not take much time.

Thanks for your responses and your help.

Re: Setting up ARB using ASP Classic

soundcommerce — Tue, 23 Mar 2010 01:50:53 GMT

Glad you were able to get it resolved.

Thanks!

Re: Setting up ARB using ASP Classic

Youngahn9191 — Mon, 28 Mar 2011 20:12:43 GMT

Hi dear,

I think I will face same problem you had.

How did you accomplish your ARB with other's help?

Is it possilbe that the ARB can be done with in classic ASP?

Only language what I know it that ASP with some basic XML.

I need to integrate with my subscription website.

Give some your advice for the late comer with ASP.

Best,

David

Re: Setting up ARB using ASP Classic

muddassirr — Thu, 14 Apr 2011 20:53:40 GMT

Can you please share your working code with others. Thanks

Re: Setting up ARB using ASP Classic

kamalsabapathi — Thu, 05 Jul 2012 13:02:59 GMT

hi all,

how to implement Automated Recurring Billing (ARB) on authorize.net using classic asp,

Please help me any one

thanks

Kamal.S

Re: Setting up ARB using ASP Classic

Michelle — Fri, 06 Jul 2012 16:55:29 GMT

Hey Kamal.S,

You can check out our sample code page for some examples of AIM/SIM in ASP Classic. Then for more info on ARB, please have a look at our ARB guides. Hopefully this will help you out.

Thanks,

Michelle

Developer Community Manager

Re: Setting up ARB using ASP Classic

kamalsabapathi — Sat, 21 Jul 2012 10:50:50 GMT

hi dzarro

actully i tried on your code...but its showing invalid token...valiid token is "or"...what does it mean?

Re: Setting up ARB using ASP Classic

kamalsabapathi — Sat, 21 Jul 2012 10:52:57 GMT

Hi Michell....

i Tried with u r instruction...but still its not working...can u send me the correct code classic asp

Re: Setting up ARB using ASP Classic

Michelle — Wed, 25 Jul 2012 17:23:46 GMT

Hey again,

We don't have sample code for ARB in ASP Classic. If that's what you're looking for, you'll need to find that elsewhere. If you're having a problem with any of the code we do have in ASP, then you can post the code and the response you're getting and we can try to troubleshoot.

Thanks,

Michelle

Developer Community Manager

Re: Setting up ARB using ASP Classic

snooper — Tue, 15 Oct 2013 09:38:49 GMT

how disappointing that you cant supply sample code for ASP

Re: Setting up ARB using ASP Classic

gurudave — Wed, 18 Feb 2015 16:47:16 GMT

Some of you all have requested sample code. Based on dzarro's original code and later comments, I put together working code for ARB entry using ASP Classic. Here you go:

KID = "recurtest"
theName = "Recur TEST Member Subscription"
theDate = "2015-05-27"
numOccur = "12"
amt = "423.45"

txtCCExp = "2029-07"
txtCCNum = "4111111111111111"
txtBillingFName = "Test"
txtBillingLName = "Person"
txtBillingAddress = "123 E. 4th"
txtBillingZip = "12345"

strTransKey = "xxxxxxxxxxxxxxxx"
apiLogin = "xxxxxxxxxxx"
post_url = "https://apitest.authorize.net/xml/v1/request.api"

strXml = "<?xml version='1.0' encoding='utf-8'?>"
strXml = strXml & "<ARBCreateSubscriptionRequest xmlns='AnetApi/xml/v1/schema/AnetApiSchema.xsd'>"
strXml = strXml & "<merchantAuthentication>"
strXml = strXml & "<name>" & apiLogin & "</name>"
strXml = strXml & "<transactionKey>" & strTransKey & "</transactionKey>"
strXml = strXml & "</merchantAuthentication>"
strXml = strXml & "<refId>" & KID & "</refId>"
strXml = strXml & "<subscription>"
strXml = strXml & "<name>" & theName & "</name>"
strXml = strXml & "<paymentSchedule>"
strXml = strXml & "<interval>"
strXml = strXml & "<length>1</length>"
strXml = strXml & "<unit>months</unit>"
strXml = strXml & "</interval>"
strXml = strXml & "<startDate>" & theDate & "</startDate>"
strXml = strXml & "<totalOccurrences>" & numOccur & "</totalOccurrences>"
'strXml = strXml & " <trialOccurrences>1</trialOccurrences>" & vbcrlf
strXml = strXml & "</paymentSchedule>"
strXml = strXml & "<amount>" & amt & "</amount>"
'strXml = strXml & " <trialAmount>0.00</trialAmount>" & vbcrlf
strXml = strXml & "<payment>"
strXml = strXml & "<creditCard>"
strXml = strXml & "<cardNumber>" & txtCCNum & "</cardNumber>"
strXml = strXml & "<expirationDate>" & txtCCExp & "</expirationDate>"
strXml = strXml & "</creditCard>"
strXml = strXml & "</payment>"
strXml = strXml & "<billTo>"
strXml = strXml & "<firstName>" & txtBillingFName & "</firstName>"
strXml = strXml & "<lastName>" & txtBillingLName & "</lastName>"
strXml = strXml & "<address>" & txtBillingAddress & "</address>"
strXml = strXml & "<zip>" & txtBillingZip & "</zip>"
strXml = strXml & "</billTo>"
strXml = strXml & "</subscription>"
strXml = strXml & "</ARBCreateSubscriptionRequest>"

Set objXMLDOC = Server.CreateObject("Msxml2.ServerXMLHTTP.3.0")
Set objXMLDOM = Server.CreateObject("Msxml2.DomDocument")
Set oNode = Server.CreateObject("Microsoft.XMLDOM")

'SET CALL TIMEOUTS
lResolve = 8 * 1000 'Timeout values are in milli-seconds
lConnect = 8 * 1000
lSend = 10 * 1000
lReceive = 10 * 1000
objXMLDOC.setTimeouts lResolve, lConnect, lSend, lReceive

'MAKE THE CALL
objXMLDOC.open "POST", post_url, False
objXMLDOC.setRequestHeader "Content-Type", "text/xml"
objXMLDOC.send(strXml)
objXMLDOM.async = false
objXMLDOM.LoadXML objXMLDOC.responseText

'output response to screen (view source to see tags)

'response.write objXMLDOC.responseText & " "

'PROCESS THE CALL
If objXMLDOM.parseError.errorCode <> 0 Then 'parser error found
Response.Write "parser error found"
Else 'no parser error
'BEGIN CHECK FOR ERROR FROM Authorize.net
'Set oNode = objXMLDOM.getElementsByTagName("*")
'Response.Write "oNode length = " & oNode.length & " "
Set oNode = objXMLDOM.getElementsByTagName("resultCode")
If (oNode.item(0).text="Error") Then
 Set oNode = objXMLDOM.getElementsByTagName("text")
 Response.Write "Error: " & oNode.item(0).text & " "
Else
 'PROCESS SUCCESSFUL CALL
 Set oNode = objXMLDOM.getElementsByTagName("subscriptionId")
 If (Not oNode Is Nothing) Then
 Response.Write "subscriptionId returned " & oNode.item(0).text & " "
 else
 Response.Write "subscriptionId not returned" & " "
 End If
End If

Set oNode = Nothing

End If

Set objXMLDOC = Nothing
Set objXMLDOM = Nothing
%>

Re: Setting up ARB using ASP Classic

drewdub — Thu, 14 Apr 2016 18:14:24 GMT

Where I can I get the ASp sample code? it's not on the samples page anywhere...